Initial commit

2 files changed, 180 insertions, 0 deletions

diff --git a/.oh-my-zsh/plugins/pip/_pip b/.oh-my-zsh/plugins/pip/_pip
new file mode 100644
index 0000000..607f68e
--- /dev/null
+++ b/.oh-my-zsh/plugins/pip/_pip
@@ -0,0 +1,99 @@
+#compdef pip pip2 pip-2.7 pip3 pip-3.2 pip-3.3 pip-3.4
+#autoload
+
+# pip zsh completion, based on last stable release (pip8)
+# homebrew completion and backwards compatibility
+
+_pip_all() {
+  # we cache the list of packages (originally from the macports plugin)
+  if (( ! $+piplist )); then
+      zsh-pip-cache-packages
+      piplist=($(cat $ZSH_PIP_CACHE_FILE))
+  fi
+}
+
+_pip_installed() {
+  installed_pkgs=(`pip freeze | cut -d '=' -f 1`)
+}
+
+local -a _1st_arguments
+_1st_arguments=(
+  'install:install packages'
+  'download:download packages'
+  'uninstall:uninstall packages'
+  'freeze:output all currently installed packages (exact versions) to stdout'
+  'list:list installed packages'
+  'show:show information about installed packages'
+  'search:search PyPI'
+  'wheel:build individual wheel archives for your requirements and dependencies'
+  'hash:compute a hash of a local package archive'
+  'help:show available commands'
+  'bundle:create pybundles (archives containing multiple packages)(deprecated)'
+  'unzip:unzip individual packages(deprecated)'
+  'zip:zip individual packages(deprecated)'
+)
+
+local expl
+local -a all_pkgs installed_pkgs
+
+_arguments \
+  '(-h --help)'{-h,--help}'[show help]' \
+  '(--isolated)--isolated[run pip in isolated mode, ignores environment variables and user configuration]' \
+  '(-v --verbose)'{-v,--verbose}'[give more output]' \
+  '(-V --version)'{-V,--version}'[show version number of program and exit]' \
+  '(-q --quiet)'{-q,--quiet}'[give less output]' \
+  '(--log)--log[log file location]' \
+  '(--proxy)--proxy[proxy in form user:passwd@proxy.server:port]' \
+  '(--retries)--retries[max number of retries per connection (default 5 times)]' \
+  '(--timeout)--timeout[socket timeout (default 15s)]' \
+  '(--exists-action)--exists-action[default action when a path already exists: (s)witch, (i)gnore, (w)ipe, (b)ackup]' \
+  '(--trusted-host)--trusted-host[mark this host as trusted]' \
+  '(--cert)--cert[path to alternate CA bundle]' \
+  '(--client-cert)--client-cert[path to SSL client certificate]' \
+  '(--cache-dir)--cache-dir[store the cache data in specified directory]' \
+  '(--no-cache-dir)--no-cache-dir[disable de cache]' \
+  '(--disable-pip-version-check)--disable-pip-version-check[do not check periodically for new pip version downloads]' \
+  '(-E --environment)'{-E,--environment}'[virtualenv environment to run pip in (deprecated)]' \
+  '(-s --enable-site-packages)'{-s,--enable-site-packages}'[include site-packages in virtualenv (deprecated)]' \
+  '*:: :->subcmds' && return 0
+
+if (( CURRENT == 1 )); then
+  _describe -t commands "pip subcommand" _1st_arguments
+  return
+fi
+
+case "$words[1]" in
+  search)
+    _arguments \
+      '(--index)--index[base URL of Python Package Index]' ;;
+  freeze)
+    _arguments \
+      '(-l --local)'{-l,--local}'[report only virtualenv packages]' ;;
+  install)
+    _arguments \
+      '(-U --upgrade)'{-U,--upgrade}'[upgrade all packages to the newest available version]' \
+      '(--user)--user[install packages to user home]' \
+      '(-f --find-links)'{-f,--find-links}'[URL for finding packages]' \
+      '(-r --requirement)'{-r,--requirement}'[Requirements file for packages to install]:File:_files' \
+      '(--no-deps --no-dependencies)'{--no-deps,--no-dependencies}'[iIgnore package dependencies]' \
+      '(--no-install)--no-install[only download packages]' \
+      '(--no-download)--no-download[only install downloaded packages]' \
+      '(--install-option)--install-option[extra arguments to be supplied to the setup.py]' \
+      '(--single-version-externally-managed)--single-version-externally-managed[do not download/install dependencies. requires --record or --root]'\
+      '(--root)--root[treat this path as a fake chroot, installing into it. implies --single-version-externally-managed]'\
+      '(--record)--record[file to record all installed files to.]'\
+      '(-r --requirement)'{-r,--requirement}'[requirements file]: :_files'\
+      '(-e --editable)'{-e,--editable}'[path of or url to source to link to instead of installing.]: :_files -/'\
+      '1: :->packages' &&  return 0
+
+      if [[ "$state" == packages ]]; then
+        _pip_all
+        _wanted piplist expl 'packages' compadd -a piplist
+      fi ;;
+  uninstall)
+    _pip_installed
+    _wanted installed_pkgs expl 'installed packages' compadd -a installed_pkgs ;;
+  show)
+    _pip_installed
+    _wanted installed_pkgs expl 'installed packages' compadd -a installed_pkgs ;;
+esac
diff --git a/.oh-my-zsh/plugins/pip/pip.plugin.zsh b/.oh-my-zsh/plugins/pip/pip.plugin.zsh
new file mode 100644
index 0000000..d7236b0
--- /dev/null
+++ b/.oh-my-zsh/plugins/pip/pip.plugin.zsh
@@ -0,0 +1,81 @@
+# Usage:
+# Just add pip to your installed plugins.
+
+# If you would like to change the cheeseshops used for autocomplete set
+# ZSH_PIP_INDEXES in your zshrc. If one of your indexes are bogus you won't get
+# any kind of error message, pip will just not autocomplete from them. Double
+# check!
+#
+# If you would like to clear your cache, go ahead and do a
+# "zsh-pip-clear-cache".
+
+ZSH_PIP_CACHE_FILE=~/.pip/zsh-cache
+ZSH_PIP_INDEXES=(https://pypi.python.org/simple/)
+
+zsh-pip-clear-cache() {
+  rm $ZSH_PIP_CACHE_FILE
+  unset piplist
+}
+
+zsh-pip-clean-packages() {
+    sed -n '/<a href/ s/.*>\([^<]\{1,\}\).*/\1/p'
+}
+
+zsh-pip-cache-packages() {
+  if [[ ! -d ${ZSH_PIP_CACHE_FILE:h} ]]; then
+      mkdir -p ${ZSH_PIP_CACHE_FILE:h}
+  fi
+
+  if [[ ! -f $ZSH_PIP_CACHE_FILE ]]; then
+      echo -n "(...caching package index...)"
+      tmp_cache=/tmp/zsh_tmp_cache
+      for index in $ZSH_PIP_INDEXES ; do
+          # well... I've already got two problems
+          curl $index 2>/dev/null | \
+              zsh-pip-clean-packages \
+               >> $tmp_cache
+      done
+      sort $tmp_cache | uniq | tr '\n' ' ' > $ZSH_PIP_CACHE_FILE
+      rm $tmp_cache
+  fi
+}
+
+# A test function that validates the regex against known forms of the simple
+# index. If you modify the regex to make it work for you, you should add a test
+# case in here and make sure that your changes don't break things for someone
+# else.
+zsh-pip-test-clean-packages() {
+    local expected
+    local actual
+    expected="0x10c-asm
+1009558_nester"
+
+    actual=$(echo -n "<html><head><title>Simple Index</title><meta name=\"api-version\" value=\"2\" /></head><body>
+<a href='0x10c-asm'>0x10c-asm</a><br/>
+<a href='1009558_nester'>1009558_nester</a><br/>
+</body></html>" | zsh-pip-clean-packages)
+
+    if [[ $actual != $expected ]] ; then
+        echo -e "python's simple index is broken:\n$actual\n  !=\n$expected"
+    else
+        echo "python's simple index is fine"
+    fi
+
+    actual=$(echo -n '<html>
+  <head>
+    <title>Simple Package Index</title>
+  </head>
+  <body>
+    <a href="0x10c-asm">0x10c-asm</a><br/>
+    <a href="1009558_nester">1009558_nester</a><br/>
+</body></html>' | zsh-pip-clean-packages)
+
+    if [[ $actual != $expected ]] ; then
+        echo -e "the djangopypi2 index is broken:\n$actual\n  !=\n$expected"
+    else
+        echo "the djangopypi2 index is fine"
+    fi
+}
+
+alias pip="noglob pip" # allows square brackets for pip command invocation
+