blob: d9a8c5ed1fdf52a318f0e58b89661b288a92cf00 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
|
# MIT License, Copyright (c) 2022 Marvin Borner
# experimental functions; sometimes list-based; could work on any base
:input std/Number
:import std/List .
# adds all values in list
sum foldl add (+0) ⧗ (List Number) → Number
∑‣ sum
:test (∑((+1) : ((+2) : {}(+3)))) ((+6))
# returns max value of list
lmax foldl1 max ⧗ (List Number) → Number
:test (lmax ((+1) : ((+3) : {}(+2)))) ((+3))
# returns min value of list
lmin foldl1 min ⧗ (List Number) → Number
:test (lmin ((+2) : ((+1) : {}(+0)))) ((+0))
# converts number to list of its digits
digits z [[rec]] ⧗ Number → (List Number)
rec =?0 case-end case-rec
case-rec (1 (0 / (+10))) ; (0 % (+10))
case-end empty
:test (digits (+0)) (empty)
# list from num to num
{…→…} z [[[rec]]] ⧗ Number → Number → (List Number)
rec (1 =? ++0) case-end case-list
case-list 1 : (2 ++1 0)
case-end empty
:test ({ (+0) → (+2) }) ((+0) : ((+1) : {}(+2)))
# equivalent of mathematical sum function
∑…→…|… z [[[[[rec]]]]] (+0) ⧗ Number → Number → (Number → Number) → Number
rec (2 =? ++1) case-end case-sum
case-sum 4 (3 + (0 2)) ++2 1 0
case-end 3
:test (∑ (+1) → (+3) | ++‣) ((+9))
# multiplies all values in list
product foldl mul (+1) ⧗ (List Number) → Number
∏‣ product
:test (∏((+1) : ((+2) : {}(+3)))) ((+6))
# equivalent of mathematical product function
∏…→…|… z [[[[[rec]]]]] (+1) ⧗ Number → Number → (Number → Number) → Number
rec (2 =? ++1) case-end case-sum
case-sum 4 (3 ⋅ (0 2)) ++2 1 0
case-end 3
:test (∏ (+1) → (+3) | ++‣) ((+24))
# greatest common divisor
gcd z [[[(1 =? 0) case-eq ((1 >? 0) case-gre case-les)]]] ⧗ Number → Number → Number
case-eq 1
case-gre 2 (1 - 0) 0
case-les 2 1 (0 - 1)
:test ((gcd (+2) (+4)) =? (+2)) (true)
:test ((gcd (+10) (+5)) =? (+5)) (true)
:test ((gcd (+3) (+8)) =? (+1)) (true)
# power function
pow […!!… (iterate (…⋅… 0) (+1))] ⧗ Number → Number → Number
…**… pow
:test (((+2) ** (+3)) =? (+8)) (true)
# power function using ternary exponentiation (TODO: fix, wrong..)
pow* z [[[rec]]] ⧗ Number → Number → Number
rec =?0 case-end case-pow
case-pow =?(lst 0) ³(2 1 /³0) (³(2 1 /³0) ⋅ 1)
³‣ [0 ⋅ 0 ⋅ 0]
case-end (+1)
# factorial function
fac [∏ (+1) → 0 | i] ⧗ Number → Number
:test ((fac (+3)) =? (+6)) (true)
# super factorial function
superfac [∏ (+1) → 0 | fac] ⧗ Number → Number
:test ((superfac (+4)) =? (+288)) ([[1]])
# hyper factorial function
hyperfac [∏ (+1) → 0 | [0 ** 0]] ⧗ Number → Number
:test ((hyperfac (+2)) =? (+4)) (true)
:test ((hyperfac (+3)) =? (+108)) (true)
:test ((hyperfac (+4)) =? (+27648)) ([[1]])
# alternate factorial function
altfac y [[=?0 0 ((fac 0) - (1 --0))]]
:test ((altfac (+3)) =? (+5)) ([[1]])
# exponential factorial function
expfac y [[(0 =? (+1)) 0 (0 ** (1 --0))]]
:test ((expfac (+4)) =? (+262144)) ([[1]])
# inverse factorial function
invfac y [[[compare-case 1 (2 ++1 0) (-1) 0 (∏ (+0) → --1 | ++‣)]]] (+0)
:test ((invfac (+1)) =? (+0)) ([[1]])
:test ((invfac (+2)) =? (+2)) ([[1]])
:test ((invfac (+120)) =? (+5)) ([[1]])
:test ((invfac (+119)) =? (-1)) ([[1]])
# calculates a powertower
# also: [[foldr pow (+1) (replicate 0 1)]]
powertower z [[[rec]]] ⧗ Number → Number → Number
rec =?0 case-end case-rec
case-end (+1)
case-rec 1 ** (2 1 --0)
:test ((powertower (+2) (+1)) =? (+2)) (true)
:test ((powertower (+2) (+2)) =? (+4)) (true)
:test ((powertower (+2) (+3)) =? (+16)) (true)
:test ((powertower (+2) (+4)) =? (+65536)) (true)
# knuth's up-arrow notation
# arrow count → base → exponent
arrow z [[[[rec]]]] ⧗ Number → Number → Number → Number
rec =?2 case-end case-rec
case-end 1 ⋅ 0
case-rec foldr (3 --2) 1 (replicate --0 1)
:test ((arrow (+1) (+1) (+1)) =? (+1)) (true)
:test ((arrow (+1) (+2) (+4)) =? (+16)) (true)
:test ((arrow (+2) (+2) (+4)) =? (+65536)) (true)
# fibonacci sequence
# TODO: faster fib?
fibs head <$> (iterate [~0 : (^0 + ~0)] ((+0) : (+1))) ⧗ (List Number)
fib [fibs !! ++0] ⧗ Number
:test (fib (+5)) ((+8))
# floored integer square root using Babylonian method
sqrt [z [[[[rec]]]] (+1) 0 0] ⧗ Number → Number
rec (1 >? 2) case-rec case-end
case-rec [4 (1 / 0) 0 1] /²(2 + 1)
case-end 1
:test ((sqrt (+0)) =? (+0)) (true)
:test ((sqrt (+1)) =? (+1)) (true)
:test ((sqrt (+2)) =? (+1)) (true)
:test ((sqrt (+5)) =? (+2)) (true)
:test ((sqrt (+9)) =? (+3)) (true)
# integer logarithm
log z [[[[rec]]]] (+1) ⧗ Number → Number → Number
rec [((3 ≤? 1) ⋀? (1 <? 0)) case-end case-rec] (2 ⋅ 1)
case-end (+0)
case-rec ++(4 0 2 1)
:test ((log (+2) (+1)) =? (+0)) (true)
:test ((log (+2) (+2)) =? (+1)) (true)
:test ((log (+2) (+3)) =? (+1)) (true)
:test ((log (+2) (+4)) =? (+2)) (true)
:test ((log (+2) (+32)) =? (+5)) (true)
:test ((log (+2) (+48)) =? (+5)) (true)
# iterated logarithm
# note that log* 1 is defined as 1
log* [z [[rec]] --0] ⧗ Number → Number
rec (0 ≤? (+1)) case-end case-rec
case-end (+1)
case-rec ++(1 (log (+2) 0))
:test ((log* (+1)) =? (+1)) (true)
:test ((log* (+2)) =? (+1)) (true)
:test ((log* (+3)) =? (+2)) (true)
:test ((log* (+4)) =? (+2)) (true)
:test ((log* (+5)) =? (+3)) (true)
:test ((log* (+16)) =? (+3)) (true)
:test ((log* (+17)) =? (+4)) (true)
:test ((log* (+65536)) =? (+4)) (true)
:test ((log* (+65537)) =? (+5)) (true)
# pascal triangle
# TODO: something is wrong in here
pascal iterate [zip-with …+… ({}(+0) ++ 0) (0 ; (+0))] ({}(+1))
# characteristic prime sequence by Tromp
characteristic-primes ki : (ki : (sieve s0)) ⧗ (List Bool)
sieve y [[k : ([(2 0) (y' 0)] (ssucc 0))]]
y' [[0 0] [1 (0 0)]]
ssucc [[[[1 : (0 (3 2))]]]]
s0 [[[ki : (0 2)]]]
# prime number sequence
primes map fst (filter snd (zip (iterate ++‣ (+0)) characteristic-primes)) ⧗ (List Number)
# slower but cooler prime number sequence
primes* nub ((…≠?… (+1)) ∘∘ gcd) (iterate ++‣ (+2)) ⧗ (List Number)
# π as a list of decimal digits
# translation of unbounded spigot algorithm by Jeremy Gibbons
# TODO: faster!
# → BBP/Bellard's formula with ternary base?
# TODO: |log|, better primes/mod/div
π g (+1) (+180) (+60) (+2) ⧗ (List Number)
g z [[[[[calc]]]]]
calc b : (4 q r t i)
a ↑⁰(↑⁺0 ⋅ (↑⁰0 + (+2)))
b (3 ⋅ ↑⁰(↑⁻(↑⁻0)) + ((+5) ⋅ 2)) / ((+5) ⋅ 1)
q (+10) ⋅ 3 ⋅ 0 ⋅ --((+2) ⋅ 0)
r (+10) ⋅ a ⋅ (3 ⋅ ((+5) ⋅ 0 - (+2)) + 2 - (b ⋅ 1))
t 1 ⋅ a
i ++0
|
