std/Pair.bruijn


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# MIT License, Copyright (c) 2022 Marvin Borner

:import std/Combinator .

# pairs two expressions into one
pair [[[0 2 1]]]

(:) pair

# extracts first expression from pair
fst [0 k]

^( fst

:test (^([[0]] : [[1]])) ([[0]])

# extracts second expression from pair
snd [0 ki]

~( snd

:test (~([[0]] : [[1]])) ([[1]])

# applies both elements of a pair to a function
uncurry [[1 ^0 ~0]]

:test (uncurry w ([[0]] : [[1]])) ([[1]])

# applies a function to the pair of two values
curry [[[2 (1 : 0)]]]

:test (curry fst [[0]] [[1]]) ([[0]])

# zips two pairs (basically rotating the elements)
zip [[(^1 : ^0) : (~1 : ~0)]]

:test (zip ([[0]] : [[[0]]]) ([[1]] : [[[1]]])) (([[0]] : [[1]]) : ([[[0]]] : [[[1]]]))

# applies pairs of two pairs as arguments to a function
zip-with [[[(2 ^1 ^0) : (2 ~1 ~0)]]]

:test (zip-with w ([[0]] : [[[0]]]) ([[1]] : [[[1]]])) ([[1]] : [0])

# swaps the elements of a pair
swap [~0 : ^0]

:test (swap ([[0]] : [[1]])) ([[1]] : [[0]])