3 files changed, 125 insertions, 0 deletions
diff --git a/.oh-my-zsh/plugins/extract/README.md b/.oh-my-zsh/plugins/extract/README.md
new file mode 100644
index 0000000..83b878c
--- /dev/null
+++ b/.oh-my-zsh/plugins/extract/README.md
@@ -0,0 +1,47 @@
+# extract plugin
+
+This plugin defines a function called `extract` that extracts the archive file
+you pass it, and it supports a wide variety of archive filetypes.
+
+This way you don't have to know what specific command extracts a file, you just
+do `extract <filename>` and the function takes care of the rest.
+
+To use it, add `extract` to the plugins array in your zshrc file:
+
+```zsh
+plugins=(... extract)
+```
+
+## Supported file extensions
+
+| Extension         | Description                          |
+|:------------------|:-------------------------------------|
+| `7z`              | 7zip file                            |
+| `Z`               | Z archive (LZW)                      |
+| `apk`             | Android app file                     |
+| `aar`             | Android library file                 |
+| `bz2`             | Bzip2 file                           |
+| `deb`             | Debian package                       |
+| `gz`              | Gzip file                            |
+| `ipsw`            | iOS firmware file                    |
+| `jar`             | Java Archive                         |
+| `lzma`            | LZMA archive                         |
+| `rar`             | WinRAR archive                       |
+| `sublime-package` | Sublime Text package                 |
+| `tar`             | Tarball                              |
+| `tar.bz2`         | Tarball with bzip2 compression       |
+| `tar.gz`          | Tarball with gzip compression        |
+| `tar.xz`          | Tarball with lzma2 compression       |
+| `tar.zma`         | Tarball with lzma compression        |
+| `tbz`             | Tarball with bzip compression        |
+| `tbz2`            | Tarball with bzip2 compression       |
+| `tgz`             | Tarball with gzip compression        |
+| `tlz`             | Tarball with lzma compression        |
+| `txz`             | Tarball with lzma2 compression       |
+| `war`             | Web Application archive (Java-based) |
+| `xpi`             | Mozilla XPI module file              |
+| `xz`              | LZMA2 archive                        |
+| `zip`             | Zip archive                          |
+
+See [list of archive formats](https://en.wikipedia.org/wiki/List_of_archive_formats) for
+more information regarding archive formats.
diff --git a/.oh-my-zsh/plugins/extract/_extract b/.oh-my-zsh/plugins/extract/_extract
new file mode 100644
index 0000000..33d49fc
--- /dev/null
+++ b/.oh-my-zsh/plugins/extract/_extract
@@ -0,0 +1,7 @@
+#compdef extract
+#autoload
+
+_arguments \
+  '(-r --remove)'{-r,--remove}'[Remove archive.]' \
+  "*::archive file:_files -g '(#i)*.(7z|Z|apk|aar|bz2|deb|gz|ipsw|jar|lzma|rar|sublime-package|tar|tar.bz2|tar.gz|tar.xz|tar.zma|tbz|tbz2|tgz|tlz|txz|war|whl|xpi|xz|zip)(-.)'" \
+    && return 0
diff --git a/.oh-my-zsh/plugins/extract/extract.plugin.zsh b/.oh-my-zsh/plugins/extract/extract.plugin.zsh
new file mode 100644
index 0000000..5e9b9ff
--- /dev/null
+++ b/.oh-my-zsh/plugins/extract/extract.plugin.zsh
@@ -0,0 +1,71 @@
+alias x=extract
+
+extract() {
+	local remove_archive
+	local success
+	local extract_dir
+
+	if (( $# == 0 )); then
+		cat <<-'EOF' >&2
+			Usage: extract [-option] [file ...]
+
+			Options:
+			    -r, --remove    Remove archive after unpacking.
+		EOF
+	fi
+
+	remove_archive=1
+	if [[ "$1" == "-r" ]] || [[ "$1" == "--remove" ]]; then
+		remove_archive=0
+		shift
+	fi
+
+	while (( $# > 0 )); do
+		if [[ ! -f "$1" ]]; then
+			echo "extract: '$1' is not a valid file" >&2
+			shift
+			continue
+		fi
+
+		success=0
+		extract_dir="${1:t:r}"
+		case "${1:l}" in
+			(*.tar.gz|*.tgz) (( $+commands[pigz] )) && { pigz -dc "$1" | tar xv } || tar zxvf "$1" ;;
+			(*.tar.bz2|*.tbz|*.tbz2) tar xvjf "$1" ;;
+			(*.tar.xz|*.txz)
+				tar --xz --help &> /dev/null \
+				&& tar --xz -xvf "$1" \
+				|| xzcat "$1" | tar xvf - ;;
+			(*.tar.zma|*.tlz)
+				tar --lzma --help &> /dev/null \
+				&& tar --lzma -xvf "$1" \
+				|| lzcat "$1" | tar xvf - ;;
+			(*.tar) tar xvf "$1" ;;
+			(*.gz) (( $+commands[pigz] )) && pigz -d "$1" || gunzip "$1" ;;
+			(*.bz2) bunzip2 "$1" ;;
+			(*.xz) unxz "$1" ;;
+			(*.lzma) unlzma "$1" ;;
+			(*.z) uncompress "$1" ;;
+			(*.zip|*.war|*.jar|*.sublime-package|*.ipsw|*.xpi|*.apk|*.aar|*.whl) unzip "$1" -d $extract_dir ;;
+			(*.rar) unrar x -ad "$1" ;;
+			(*.7z) 7za x "$1" ;;
+			(*.deb)
+				mkdir -p "$extract_dir/control"
+				mkdir -p "$extract_dir/data"
+				cd "$extract_dir"; ar vx "../${1}" > /dev/null
+				cd control; tar xzvf ../control.tar.gz
+				cd ../data; extract ../data.tar.*
+				cd ..; rm *.tar.* debian-binary
+				cd ..
+			;;
+			(*)
+				echo "extract: '$1' cannot be extracted" >&2
+				success=1
+			;;
+		esac
+
+		(( success = $success > 0 ? $success : $? ))
+		(( $success == 0 )) && (( $remove_archive == 0 )) && rm "$1"
+		shift
+	done
+}